NAM Version 39 Now Available!

[Dono 178]

13 hours ago, Tarkus said:

Thanks for the kind words!  To answer your question, it's not really all that documented, but the FLEX piece for the One-Tile Roundabouts is designed just to cover the multi-network (Road x Street) situation.  To build the same-network combos (Road x Road or Street x Street), build a + or T-intersection as one normally would, then click directly over the intersection with the Rail tool.  It'll convert to a roundabout.

Hope that helps!

-Tarkus

Thank you so much, my rural areas will love having no traffic lights and so simple... my pants just spontaneously combusted!!  

[Ramona Brie 121]

39 minutes ago, Dono said:

Thank you so much, my rural areas will love having no traffic lights and so simple... my pants just spontaneously combusted!!  

Next time you build a Road x Road intersection (T or +), try ending the road a tile early and dragging Street to the crossing road...

[Tarkus 6,932]

Also, if anyone is still having difficulty with crashing/the 4GB Patch process, I've written up a batch file which should work.  Unzip the NetworkAddonMod_Setup_Version39.zip file into its own folder (or place this in any folder that has a copy of 4gb_patch.exe), then place the .bat file contained in here into that folder.  It reads the registry, so it should pick up your SC4 installation directory and the location of SimCity 4.exe.

Should this do the job, I'll add this routine to the .bat script for NAM 40. 

-Tarkus

SimCity4_4GB_Patch_Script.zip

[Ramona Brie 121]

You can also do this to T and + intersections with avenues (not shown here is the road T + street, which you can see above in the lower right):

This feature has existed since eggman121 added it to NAM 37 (it is an adjunct to the Flex Turn Lanes), so you almost certainly as a user have it now.

[CorinaMarie 29,605]

15 hours ago, Tarkus said:

Should this do the job, I'll add this routine to the .bat script for NAM 40.

Both @Cyclone Boom and I have tested your script and it works perfectly for us. Mine is the GOG version and his is Disc based.

 

Now, on the off chance that permission is denied to the 4 GB Patch program it does show its own error message. In case peeps click that away without realizing, I've tweaked your batch file (and CB and I have tested it on each our own systems) to add its own check to see if the date and time modified for SimCity 4.exe have changed as expected. If not, then it'll display its own message. This would be where you could have it abort the installation if you wanted peeps to get the patch working before proceeding with the rest.

Should you happen to want this, here's the code:

:WhatIsThis
  :: ---------------------------------------------------------------------
  ::  This is a command script written by Tarkus (Alex) and Cori to apply
  ::   the 4 GB Patch to SimCity 4.exe and check that it was successful.
  :: ---------------------------------------------------------------------

:Start
  @Echo Off
  FOR /F "usebackq tokens=3,* skip=2" %%L IN (
      `reg query "HKLM\SOFTWARE\WOW6432Node\Maxis\SimCity 4" /v "Install Dir"`
  ) DO SET sc4dir=%%M\Apps

:AnotherSetCommand
  SET GameExe=SimCity 4.exe

:CheckLocation
  If NOT Exist "%sc4dir%\%GameExe%" Goto :LostFile

:SaveBeforeDateTime
   Dir "%sc4dir%\%GameExe%" /T:W | FIND /i "SimCity 4.exe" > %temp%\TempDateTimeCheckBefore.txt"

:ApplyPatch
  Start "" /wait 4gb_patch.exe "%sc4dir%\SimCity 4.exe"

:SaveAfterDateTime
   Dir "%sc4dir%\%GameExe%" /T:W | FIND /i "SimCity 4.exe" > %temp%\TempDateTimeCheckAfter.txt"

:CompareDateTime
  FC %temp%\TempDateTimeCheckBefore.txt %temp%\TempDateTimeCheckAfter.txt > NUL
  If ErrorLevel 2 Goto :Error
  If ErrorLevel 1 Goto :Success
  Goto :Fail

:LostFile
  Echo "%sc4dir%\%GameExe%"
  Echo   was not found as expected.
  Goto :Exit

:Error
  :: Note, this should not occur, but we trap for it just in case writing to the TEMP folder is denied.
  Echo Temp file creation for checking the date / time stamp failed.
  Echo   Look at the following and check if the date and time is current:
  Echo.
  Dir "%sc4dir%\%GameExe%" /T:W | FIND /i "SimCity 4.exe"
  Goto :Cleanup

:Fail
  Echo * * * ERROR * * *
  Echo.
  Echo The 4 GB Patch was NOT successfully applied. :(
  Goto :CleanUp

:Success
  Echo The 4 GB Patch was successfully applied - ready for NAM installation. :)
  Goto :CleanUp

:CleanUp
  If Exist %temp%\TempDateTimeCheckBefore.txt Del %temp%\TempDateTimeCheckBefore.txt
  If Exist %temp%\TempDateTimeCheckAfter.txt Del %temp%\TempDateTimeCheckAfter.txt

:Exit
  Echo.
  Pause

^ Note: The last line is deliberately an empty CR/LF because there are rare times when a batch file will go goofy without that.

And, ofc, if this is unwanted, feel free to skip it.

[Tarkus 6,932]

@CorinaMarie, you are officially awesome for snazzing up the batch script!  (And thanks to you and CB for testing it!)

If you have no objections, I'd definitely be onboard with including it as part of the NAM 40 download (with full credit given).

-Tarkus

[CorinaMarie 29,605]

3 hours ago, Tarkus said:

If you have no objections, I'd definitely be onboard with including it as part of the NAM 40 download (with full credit given).

No objections at all. Tis why I wrote it in case it'd be useful to y'all. (Now that I know you want it, I'll spice it up with full embedded comments which I'll post later today.)

The same applies to the Lua code I wrote ( Cori's Coded Solution to the Canal Boats Creation Issue ) which fixes the canal boats generator as well as the associated documentation and pics in that thread. (Assuming it's not already been included since I'm still using 36 and haven't checked all the additions since then.)

[rsc204 21,808]

2 hours ago, CorinaMarie said:

The same applies to the Lua code I wrote ( Cori's Coded Solution to the Canal Boats Creation Issue ) which fixes the canal boats generator as well as the associated documentation and pics in that thread. (Assuming it's not already been included since I'm still using 36 and haven't checked all the additions since then.)

I thought the LUA code came with the separate stations package on the LEX, but I could be mistaken.

[CorinaMarie 29,605]

Just now, rsc204 said:

I thought the LUA code came with the separate stations package on the LEX, but I could be mistaken.

Hmmm. That's prolly true. Either way something ought to be updated if not already.

Ofc, it makes sense to me they'd be included in NAM to simplify things for everyone. (That's up to the powers that be tho.)

[rsc204 21,808]

I think the reason they were not, was simply because Automata are not technically necessary for things to function. To include the script, sort of requires we include the models (automata), which is a permission issue at it’s core. But it also runs against NAM team policy to include such things, everything we add to NAM, adds to the support side too. It doesn’t help either than CAN-AM wasn’t a particularly popular addition, development pretty much stalled after it’s initial release. A shame really, because small stretches of functioning canals can be really useful.

As such an official update, rather than the patches we have now, requires someone with the necessary seniority over at SC4D to implement. 

[CorinaMarie 29,605]

1 hour ago, rsc204 said:

It doesn’t help either than CAN-AM wasn’t a particularly popular addition, development pretty much stalled after it’s initial release.

Maybe because the silly boats wouldn't generate?

 

1 hour ago, rsc204 said:

As such an official update, rather than the patches we have now, requires someone with the necessary seniority over at SC4D to implement.

If someone simply created brand new models (one for passengers and one for freight) new lots could be created afresh from whole cloth and then the Lua modified to reference them.

[rsc204 21,808]

46 minutes ago, CorinaMarie said:

Maybe because the silly boats wouldn't generate?

Feedback generally indicates people found it too complex to use and disliked the lack of slope tolerance. 

48 minutes ago, CorinaMarie said:

If

Yes, big if mind, considering suitable models exist.

I guess too, with the whole rigmarole of installing those stations, some just got bored. The dependencies list, like for my lots, scares a lot of casual users away. I agree a more streamlined process for installing that package would probably be beneficial. Maybe one download for the scripts and automata, which might be better off in NAM. Then have the stations an optional download, split by canal type. It was only very recently (NAM 37), that default stations for CAN-AM (dependency free) were part of the NAM. So it’s no longer as unthinkable to add the cosmetic automata stuff as it once was. 

[City_Slider 2,716]

On 16/12/2020 at 1:28 PM, Tarkus said:

BTW, thanks to everyone who cast their vote for us over at ModDB (and thanks to @Cyclone Boom and @CorinaMarie for putting it on the front page)!  Unfortunately, we didn't quite make it into the next round (top-100), but I'm hoping it at least got us a little more notice. 

Just to let You know:

https://simforum.de/index.php?threads/200261/

Guess Andreas forgot it to set.

[CorinaMarie 29,605]

@Tarkus

Here's the updated version:

@Echo Off

:WhatIsThis
  :: ---------------------------------------------------------------------
  ::  This is a command script written by Tarkus (Alex) and Cori to apply
  ::   the 4 GB Patch to SimCity 4.exe and check that it was successful.
  :: ---------------------------------------------------------------------

:Show
  Echo.
  Echo SimCity4_4GB_Patch_Script_v3.bat
  Echo --------------------------------
  Echo This command script automates applying the 4 GB Patch to SimCity 4.exe.
  Echo.

:Check
  :: See if the 4gb_patch.exe file is in the same folder as this script.
  If NOT Exist 4gb_patch.exe Goto :Missing

:Start
  :: This block peeks inside the registry to find the expected location of the SimCity 4.exe file.
  FOR /F "usebackq tokens=3,* skip=2" %%L IN (
      `reg query "HKLM\SOFTWARE\WOW6432Node\Maxis\SimCity 4" /v "Install Dir"`
  ) DO SET sc4dir=%%M\Apps

:AnotherSetCommand
  :: Creates a variable we can use later.
  SET GameExe=SimCity 4.exe

:CheckLocation
  :: Check in the folder specified by the registry to make sure SimCity 4.exe is found there.
  If NOT Exist "%sc4dir%\%GameExe%" Goto :LostFile

:SaveBeforeDateTime
   :: Create a temporary file containing the last modified date and time of SimCity 4.exe before running the 4gb_patch.exe program.
   Dir "%sc4dir%\%GameExe%" /T:W | FIND /i "SimCity 4.exe" > %temp%\TempDateTimeCheckBefore.txt"

:ApplyPatch
  :: Run the patch program on the game file. Wait till that completes before proceeding with additional commands in this script.
  Start "" /wait 4gb_patch.exe "%sc4dir%\SimCity 4.exe"

:SaveAfterDateTime
   :: Create a temporary file containing the last modified date and time of SimCity 4.exe after running the 4gb_patch.exe program.
   Dir "%sc4dir%\%GameExe%" /T:W | FIND /i "SimCity 4.exe" > %temp%\TempDateTimeCheckAfter.txt"

:CompareDateTime
  :: Use the OS's FC (File Compare) program to see if the two text files are the same or different.
  ::   In this case, we actually want the compare to fail and say they are not identical.
  ::   Note that the ErrorLevel inquiry must be checked from highest to lowest because it means 'at least' whatever number is checked.
  ::   We redirect the output to NUL so only our messages will show depending on the outcome.
  FC %temp%\TempDateTimeCheckBefore.txt %temp%\TempDateTimeCheckAfter.txt > NUL

  :: Error 2 is if one or both of the files to compare are not found. (This should not happen, but we check just in case.)
  If ErrorLevel 2 Goto :Error

  :: Error 1 is when the files are not identical. In this case, that's what we want to see.
  If ErrorLevel 1 Goto :Success

  :: If the Error is zero, then the files match. In this case it tells us SimCity 4.exe was not patched.
  ::   This is a "fall thru" where neither of the above ErrorLevel checks execute their Goto.
  Goto :Fail

:Missing
  :: This is the message displayed if we did not find 4gb_patch.exe in the same folder as this script file.
  Echo.
  Echo * * * ERROR * * *
  Echo.
  Echo The 4gb_patch.exe file was not found in this folder.
  Goto :Exit

:LostFile
  :: This is the message displayed if we did not find SimCity 4.exe where the registry says it should be.
  Echo.
  Echo * * * ERROR * * *
  Echo.
  Echo "%sc4dir%\%GameExe%"
  Echo   was not found as expected.
  Goto :Exit

:Error
  :: This is the message if the File Compare of our temp text files failed.
  ::  (Should never happen, but could if writing to the TEMP folder is denied.)
  Echo.
  Echo * * * ERROR * * *
  Echo.
  Echo Temp file creation for checking the date / time stamp failed.
  Echo   Look at the following and check if the date and time is current:
  Echo.
  Dir "%sc4dir%\%GameExe%" /T:W | FIND /i "SimCity 4.exe"
  Goto :Cleanup

:Fail
  :: This is the message if the file compare shows the date and time of SimCity 4.exe to be the same before and after trying to patch it.
  Echo.
  Echo * * * ERROR * * *
  Echo.
  Echo The 4 GB Patch was NOT applied. :(
  Goto :CleanUp

:Success
  :: This is the message if the file compare shows the date and time of SimCity 4.exe to be different before and after patching it.
  Echo.
  Echo The 4 GB Patch was successfully applied - ready for NAM installation. :)
  Goto :CleanUp

:CleanUp
  :: This simply removes the two temp text files we created if they exist in the TEMP folder.
  If Exist %temp%\TempDateTimeCheckBefore.txt Del %temp%\TempDateTimeCheckBefore.txt
  If Exist %temp%\TempDateTimeCheckAfter.txt Del %temp%\TempDateTimeCheckAfter.txt

:Exit
  :: All done. We wait for the user to press the 'ANY' key before closing the Dos Command Window.
  Echo.
  Pause

^ Once copied to your fav text editor, it's best to view with word wrap turned off.
 

I'm tentatively calling it SimCity4_4GB_Patch_Script_v3.bat with the idea yours was version 1 and my prior posted was version 2, but you can make it whatever you feel is best. I do have it now also showing the file name so if you make the name anything different, change line 11 to reflect that. (The dashes in line 12 are the number needed to exactly underline the name.) Ofc, we could have it pick up the name from the batch file itself by displaying %0, but then it'd need some fancy code to make the number of underline dashes match.

It could also logically either have no version number or make it version 1 since it'll be the first released to the public. You can decide whatever is best. Ofc, in your NAM installation instructions you'll prolly want to tell peeps to take a screenshot of the batch script window if any of the error messages appear and by having a version number displayed, you'll know specifically which script they've used. (This is in case we find it needs any additional tweaking.)

Things it does:

• Display a message with the batch file name and a short description.
• Checks that the 4gb_patch.exe program is in the folder with the batch file.
• Checks that SimCity 4.exe is found where the registry says it should be.
• Creates temp text files containing the last modified date and time of the game's file before and after running the patch.
• Runs the patch program.
• Compares those two temp text files hoping to see they are different. (Messages displayed based on the outcome.)
• Removes those two temp text files.
• Waits for the user to press the ANY key before exiting.

[Durfsurn 539]

That is some snazzy code Cori! You have far more patience than I for such batch file programming!

[Dono 178]

On 21/12/2020 at 7:29 PM, Ramona Brie said:

You can also do this to T and + intersections with avenues (not shown here is the road T + street, which you can see above in the lower right):

This feature has existed since eggman121 added it to NAM 37 (it is an adjunct to the Flex Turn Lanes), so you almost certainly as a user have it now.

I couldn't get that one to work so I must be missing something (intellectually) but will have a play. I've been playing SC4 since it come out but have always stuck to mostly Maxis Roads/Hwys and used portions of NAM...I felt like I needed a degree in astrophysics to use it 😂....it's why it's such a great hobby, always something to learn. Thanks for everyone's input 😊. 

[1SweeTDreamS1 37]

On 12/21/2020 at 12:34 AM, Tarkus said:

Also, if anyone is still having difficulty with crashing/the 4GB Patch process, I've written up a batch file which should work.  Unzip the NetworkAddonMod_Setup_Version39.zip file into its own folder (or place this in any folder that has a copy of 4gb_patch.exe), then place the .bat file contained in here into that folder.  It reads the registry, so it should pick up your SC4 installation directory and the location of SimCity 4.exe.

Should this do the job, I'll add this routine to the .bat script for NAM 40. 

-Tarkus

SimCity4_4GB_Patch_Script.zip

TY! TY! TY! This worked!!   I was beginning to think I wasn't going to be able to use this upgrade.

For anyone still having problems, if I may suggest, follow the vid below but add in this patch. I did this and haven't had a single problem since.

 

[Ramona Brie 121]

Run the Road one tile out from the intersecting Road/Avenue and connect a Street instead.

On 12/22/2020 at 10:21 PM, Dono said:

I couldn't get that one to work so I must be missing something (intellectually) but will have a play. I've been playing SC4 since it come out but have always stuck to mostly Maxis Roads/Hwys and used portions of NAM...I felt like I needed a degree in astrophysics to use it 😂....it's why it's such a great hobby, always something to learn. Thanks for everyone's input 😊. 

 

[TylerBH94 0]

Hey folks, awesome stuff. I'm using the draggable flex turn lanes and finding that if I delete the whole road, the ftl tile leaves a residue that I can't remove. It doesn't effect the road network once I've deleted it once, but it remains even if I zone over it. Wondering if there's a fix? The RHW disconnector doesn't affect it.

[Flann 1,709]

38 minutes ago, TylerBH94 said:

Hey folks, awesome stuff. I'm using the draggable flex turn lanes and finding that if I delete the whole road, the ftl tile leaves a residue that I can't remove. It doesn't effect the road network once I've deleted it once, but it remains even if I zone over it. Wondering if there's a fix? The RHW disconnector doesn't affect it.

This was a bug introduced with NAM 38.  The culprit is RRW_RHSR_Hybrid_0x55387000.dat .  You may delete this file without causing any other issues.  Otherwise, raising or lowering the terrain will get rid of the texture.  This will be fixed in NAM 40.

[mitsos 12,853]

Hi everyone. NAM 39 is truly amazing. But i realised that maxis highway texture has been returned to default.  That's is a very disappointing for all us who are using maxis highways. Unless i missed something during installation.

[rsc204 21,808]

You'll need to remove the Network Addon Mod folder from Plugins and re-run the installer, selecting the following option:

If you are familiar with the older NAM installer system (v36 and before), those would have detected your previous install options when upgrading. Sadly the new Java installer can not do this, so every time you run the installer, you must once more select all the options you want.

[mitsos 12,853]

Hi rsc204. Well i don't want to replace maxis highway, just realised that there isn't  the option for dark textures. 

 

[Tyberius06 12,189]

2 minutes ago, mitsos said:

Hi rsc204. Well i don't want to replace maxis highway, just realised that there isn't  the option for dark textures. 

 

Most of the cosmetic Mods (like dark asphalt maxis highway) have been taken out for NAM v37 and above. I don't know if these are available in STEX from the past, before they were included to NAM as a separate mod, or if and when they will be available again.

- Tyberius

[mitsos 12,853]

Thank you Tyberius. 

[rsc204 21,808]

2 hours ago, mitsos said:

Hi rsc204. Well i don't want to replace maxis highway, just realised that there isn't  the option for dark textures. 

Right, I have the feeling this was one of the cosmetic options removed from NAM. The new installer system, without which the NAM would probably be a dead project, meant we had to re-asses what was included. Too many mods that have to be able to work with others, led to a complexity that was getting way out of hand. Such cosmetic options should be optional downloads/addons rather than included in the NAM directly.

For now, I've uploaded the file you need:

zzzMHW_Retexture_Euro.dat

This needs to load after the NAM, placing into a folder named zNAMOverrides in your Plugins folder should work.

[mitsos 12,853]

Problem solved. For those who interested

 

[rocker289 75]

This just started today I was replacing the Max highway with 6s L1.

I have used this before but today potholes showed up instead.

Anyone got a clue whats going on here?

Yes NAM39

[Tyberius06 12,189]

11 minutes ago, rocker289 said:

This just started today I was replacing the Max highway with 6s L1.

I have used this before but today potholes showed up instead.

Anyone got a clue whats going on here?

Yes NAM39

Hi!

RHW 6S A1 type ramp is only supported on ground level (L0) and not supported on L1-L4 levels due to an overhang. The B1 type, D1, E1, A2 and D2 is also supported on above ground level, but the B2 and E2 is only L0, ground level. 

With your example above you can use the D1 and/or A2 type flex ramps and DRI ramps. 

- Tyberius

[rocker289 75]

Thank you